mk/subst.mk: allow identity substitutions in SUBST_NOOP_OK=no mode

There are several cases where patterns like s|man|${PKGMANDIR}| appear in
SUBST_SED.  Up to now, these had been categorized as no-ops and required
extra code to make the package build when SUBST_NOOP_OK was set to "no".

This was against the original intention of SUBST_NOOP_OK, which was to
find outdated substitution patterns that do not occur in SUBST_FILES
anymore, most often because the packages have been updated since.

The identity substitutions do appear in the files, they just don't change
them.  Typical cases are for PKGMANDIR, DEVOSSAUDIO, PREFIX, and these
variables may well be different in another pkgsrc setup.  These patterns
are therefore excluded from the SUBST_NOOP_OK check.


(rillig)

#! /usr/bin/awk -f
# $NetBSD: subst-identity.awk,v 1.1 2020/04/29 18:33:57 rillig Exp $
#
# Tests whether a sed(1) command line consists of only identity substitutions
# like s,id,id,.
#
# See SUBST_NOOP_OK and regress/infra-unittests/subst.sh.
#

function is_safe_char(ch) {
	return ch ~ /[\t -~]/ && ch !~ /[$&*.\[\\\]^]/;
}

function is_identity_subst(s,   len, i, sep, pat) {
	len = length(s);
	if (len < 6 || substr(s, 1, 1) != "s")
		return 0;

	sep = substr(s, 2, 1);
	i = 3;
	while (i < len && substr(s, i, 1) != sep && is_safe_char(substr(s, i, 1)))
		i++;
	pat = substr(s, 3, i - 3);

	return (s == "s" sep pat sep pat sep ||
		s == "s" sep pat sep pat sep "g");
}

function main(   i) {
	for (i = 1; i + 1 < ARGC; i += 2)
		if (ARGV[i] != "-e" || !is_identity_subst(ARGV[i + 1]))
			return 0;
	return i == ARGC && ARGC > 1;
}

BEGIN {
	exit(main() ? 0 : 1);
}